Scalabium Software

SMExport advertising
Knowledge for your independence'.
Home Delphi and C++Builder tips


#170: How can I display the chevron button for toolbar?

Friends,

I sure you saw the cool feature of toolbar in all products of Microsoft (Internet Explorer, MS Office, Outlook Express etc) - when width of toolbar is less than total width of all buttons, then in right side of toolbar you see the new button with arrows (chevron sigh) and list of invisible buttons opened like popup menu by click on chevron.

Today I want to show how to add the chevron button in standard Delphi application and don't use the third-party components.

Please note that most components from third-party companies don't use this feature of common control in Windows - they created own control and draws everything (all buttons, sll bars etc) self.

As I prefer to use standard controls only (for future compartibility), I use the standard TCoolbar and TToolbar from Win32 palette in Delphi IDE which are wrappers for common controls in published library (like TEdit, TButton, TTreeView, TListView etc)

So lets's start.
You must drop the TCoolbar control to your form, add the TToolbar to some band of coolbar and add some other bands for coolbar (note that you must have a few bands for correct work of chevron).

For your TToolbar you may add any number of buttons and don't forget to set the AutoSize property in False.

The next code you may call in OnCreate event of form or in OnResize event (form or coolbar):

type 
  TSMRebarBandInfo = packed record 
    cbSize: UINT; 
    fMask: UINT; 
    fStyle: UINT; 
    clrFore: TColorRef; 
    clrBack: TColorRef; 
    lpText: PAnsiChar; 
    cch: UINT; 
    iImage: Integer; 
    hwndChild: HWnd; 
    cxMinChild: UINT; 
    cyMinChild: UINT; 
    cx: UINT; 
    hbmBack: HBitmap; 
    wID: UINT; 
    cyChild: UINT; 
    cyMaxChild: UINT; 
    cyIntegral: UINT; 
    cxIdeal: UINT; 
    lParam: LPARAM; 
    cxHeader: UINT; 
  end; 

procedure TForm1.FormCreate(Sender: TObject); 
const 
  RBBS_NOGRIPPER  = $00000100;  // never show the gripper 
  RBBS_USECHEVRON = $00000200; 
  RBBIM_IDEALSIZE = $00000200; 
var 
  i: Integer; 
  rbi: TSMRebarBandInfo; 
  R: Trect; 
begin 
  inherited; 

  {if somebuttons in toolbar are invisible, add chevron} 
  rbi.cbSize := SizeOf(rbi); 
  rbi.fMask := RBBIM_STYLE or RBBIM_IDEALSIZE; 

  for i := 1 to yourCoolBar.Bands.Count do 
  begin 
    if not Assigned(yourCoolBar.Bands[i-1].Control) or 
       not (yourCoolBar.Bands[i-1].Control is TToolbar) then continue; 

    SendMessage(yourCoolBar.Handle, RB_GETBANDINFO, i-1, LongInt(@rbi)); 
    rbi.fStyle := rbi.fStyle or RBBS_USECHEVRON; 
    rbi.fStyle := rbi.fStyle and not RBBS_NOGRIPPER; 
    with TToolbar(yourCoolBar.Bands[i-1].Control) do 
      if ButtonCount <> 0 then 
        with Buttons[ButtonCount-1] do 
          rbi.cxIdeal := Left + Width + 5; 
    SendMessage(yourCoolBar.Handle, RB_SETBANDINFO, i-1, LongInt(@rbi)); 
  end; 
end;

Of course, if some buttons change the state (visible=true/false in run- time from your code), you must call this function after every change because you must recalculate the width for "ideal" width

Now if you'll run your project and play with widths of the bands in coolbar, you'll see the standard chevron button for band where toolbar is.

Please note that you may display such chevron for every band in coolbar if width of band is less than child control. For example, you have some panel in band of coolbar with list of control and you may display this chevron if some controls are invisible on panel.

PS: in the next tip I'll publish the code how to display the popup menu with invisible buttons of toolbar by click on chevron button.


Published: April 25, 2006

See also
 
Protected Storage Viewer
Clarion Viewer
Excel Reader (dll)
Paradox to MS Access converter
SMMsg suite
SMExport suite
ABA Document Convert
Clarion to Text converter/a>
Fast Document Viewer
MAPIMail
 
 


Contact to webmaster

 

Borland Software Code Gear Scalabium Delphi tips

Copyright© 1998-2017, Scalabium Software. All rights reserved.
webmaster@scalabium.com

SMExport advertising